Datoer fra et andet system ender tit som tekst. De ligner datoer, men Excel gemmer dem ikke som tal, og så kan du ikke regne sikkert med dem eller filtrere og sortere dem som datoer. Tjek det med ER.TAL (engelsk: ISNUMBER):

B2 =ER.TAL(A2)
SAND for en rigtig dato, FALSK for en dato gemt som tekst.

En rigtig dato er et tal for Excel, så ER.TAL giver SAND. Giver den FALSK, skal teksten omregnes. Hvordan, afhænger af formatet, og især af om dag eller måned kommer først.

Sådan ser du forskel

Microsoft nævner, at tekstdatoer står venstrestillet i cellen, mens rigtige datoer står højrestillet. Det er et godt første tegn, men ikke et bevis: justeringen kan være ændret manuelt. ER.TAL er den sikre test.

Tekstdatoer er også en typisk grund til, at en pivottabel ikke vil gruppere datoerne pr. måned. Se pivottabeller med datoer.

Hvad DATOVÆRDI kan læse i Excel på dansk

DATOVÆRDI (engelsk: DATEVALUE) omregner en tekst til en dato. Microsoft skriver, at resultatet afhænger af computerens datoindstillinger. Vi har afprøvet 13 tekster på en computer med dansk område og kort datoformat dd-MM-yyyy:

Tekst =DATOVÆRDI(A2) Kommentar
01-04-2026 01-04-2026 dansk format
2026-04-01 01-04-2026 ISO-format
01-04-2026 01-04-2026 mellemrum foran gør ikke noget
01-04-2026 13:45 01-04-2026 klokkeslættet falder bort
1/4/26 01-04-2026 tocifret år
1-apr-2026 01-04-2026 forkortet måned
04/01/2026 04-01-2026 amerikansk 1. april blev til 4. januar
04/13/2026 #VÆRDI! måned 13 findes ikke
1.4.2026 #VÆRDI! punktum som skilletegn
01.04.2026 #VÆRDI! punktum som skilletegn
1. april 2026 #VÆRDI! skrevet dato
April 1, 2026 #VÆRDI! engelsk skrevet dato
20260401 #VÆRDI! ingen skilletegn

Og en rigtig dato i cellen giver også #VÆRDI!, fordi DATOVÆRDI kun tager tekst. Brug den derfor ikke på en hel kolonne uden først at tjekke med ER.TAL.

Punktummer og skrevne datoer

Tekster med punktum kan du rette, før DATOVÆRDI ser dem, ved at skifte punktummerne ud med bindestreger:

F5 =DATOVÆRDI(UDSKIFT(A5;".";"-"))
Gav 01-04-2026 for både 1.4.2026 og 01.04.2026.
F7 =DATOVÆRDI(UDSKIFT(UDSKIFT(A7;". ";"-");" ";"-"))
Gør "1. april 2026" til "1-april-2026". Gav 01-04-2026.

Tal uden skilletegn som 20260401 kan du skære op med VENSTRE, MIDT og HØJRE:

F12 =DATO(VENSTRE(A12;4);MIDT(A12;5;2);HØJRE(A12;2))
År, måned og dag. Gav 01-04-2026.

Amerikanske datoer: MM/DD/ÅÅÅÅ

Til amerikanske datoer skal du ikke bruge DATOVÆRDI. Del teksten ved skråstregerne og byg datoen med DATO, så du selv bestemmer, hvad der er måned og dag:

B2 =DATO(TEKSTEFTER(A2;"/";2);TEKSTFØR(A2;"/");TEKSTFØR(TEKSTEFTER(A2;"/");"/"))
År = teksten efter anden skråstreg, måned = før første, dag = mellem de to.

TEKSTFØR (engelsk: TEXTBEFORE) og TEKSTEFTER (engelsk: TEXTAFTER) finder teksten før og efter et skilletegn. DATO accepterer tallene som tekst.

Den ældre metode med faste positioner, =DATO(HØJRE(A2;4);VENSTRE(A2;2);MIDT(A2;4;2)), virker kun, når måned og dag altid har to cifre:

ABCDE
1 Amerikansk dato (tekst) TEKSTFØR/TEKSTEFTER VENSTRE/MIDT/HØJRE DATOVÆRDI Med klokkeslæt fjernet
2 04/01/202601-04-202601-04-202604-01-202601-04-2026
3 12/31/202631-12-202631-12-2026#VÆRDI!31-12-2026
4 4/1/202601-04-2026#VÆRDI!04-01-202601-04-2026
5 07/04/2026 13:45#VÆRDI!04-07-190007-04-202604-07-2026
Arket Amerikanske datoer. Alle resultater har datoformatet dd-mm-åååå.

Læg mærke til række 5. Med et klokkeslæt bagefter giver TEKSTEFTER “2026 13:45” som år, og det giver #VÆRDI!. Den faste metode giver uden fejl en dato i år 1900, og DATOVÆRDI giver 7. april. Kolonne E fjerner først alt efter første mellemrum:

E2 =LET(d;TEKSTFØR(A2&" ";" ");DATO(TEKSTEFTER(d;"/";2);TEKSTFØR(d;"/");TEKSTFØR(TEKSTEFTER(d;"/");"/")))
A2&" " sikrer, at der altid er et mellemrum at dele ved, også når der ikke er et klokkeslæt.

Når Excel allerede har byttet om på dag og måned

Er en amerikansk fil blevet åbnet direkte, kan skaden allerede være sket: datoer med dag 1–12 er blevet til rigtige, men forkerte datoer, og resten står som tekst. Kolonnen er blandet:

ABC
1 Kolonne efter forkert import ER.TAL Rettet dato
2 04-01-2026SAND01-04-2026
3 04/13/2026FALSK13-04-2026
4 11-12-2026SAND12-11-2026
5 12/31/2026FALSK31-12-2026
Arket Blandet kolonne. A2 og A4 er rigtige datoer, som Excel har læst forkert. A3 og A5 er tekst.
C2 =HVIS(ER.TAL(A2);DATO(ÅR(A2);DAG(A2);MÅNED(A2));DATO(TEKSTEFTER(A2;"/";2);TEKSTFØR(A2;"/");TEKSTFØR(TEKSTEFTER(A2;"/");"/")))
Er cellen en dato, byttes dag og måned. Er den tekst, deles den ved skråstregerne.

Brug kun formlen, hvis du ved, at alle datoer i kolonnen oprindeligt var amerikanske. En dato, der var dansk fra starten, bliver ellers byttet forkert. Det sikreste er at gå tilbage til kildefilen og importere den korrekt, se CSV-filer fra banken.

Uden formler: Tekst til kolonner

Skal kolonnen bare omregnes én gang, kan du bruge guiden Konvertér tekst til kolonner, som Microsoft beskriver under Data › Tekst til kolonner. Det vigtige sker i sidste trin: under Kolonnedataformat vælger du Dato og rækkefølgen, der passer til teksten. Ifølge Microsoft skal du vælge det datoformat, der passer til dataene, så Excel kan konvertere dem korrekt.

I vores afprøvning kørte et script den samme konvertering med de valg, du ellers træffer i guiden (sådan afprøver vi):

Kolonnedataformat Tekst Resultat Er et tal
Dato, MDÅ 04/01/2026 01-04-2026 ja
Dato, MDÅ 4/1/2026 01-04-2026 ja
Dato, MDÅ 12/31/2026 31-12-2026 ja
Dato, DMÅ 1.4.2026 01-04-2026 ja
Standard 04/01/2026 04-01-2026 ja
Standard 12/31/2026 12/31/2026 nej, stadig tekst

De to sidste rækker viser, hvorfor du skal vælge datoformatet selv. Med Standard gør guiden det samme som DATOVÆRDI: 1. april bliver til 4. januar, og 31. december forbliver tekst.

Når kolonnen er lavet om til rigtige datoer, kan Excel endelig regne med den. Så kan du fx regne alder og anciennitet ud fra datoerne.