En fejlværdi fortæller, hvilken slags problem formlen har ramt. Det er den hurtigste vej til årsagen, men i Excel på dansk hedder fejlene noget andet end i de engelske guides, du finder på nettet: #I/T er #N/A, #NAVN? er #NAME?, og #OVERLØB! er #SPILL!.

Tabellen giver dig oversættelsen og den mest almindelige årsag. Under den gennemgår vi hver fejl med en formel, der giver fejlen, og den rettede formel. Alt er afprøvet i Microsoft 365 Excel på dansk, og du kan hente arbejdsbogen med alle eksemplerne.

Fejlværdierne: dansk, engelsk og FEJLTYPE

Excel på dansk Engelsk Excel FEJLTYPE Oftest fordi …
#NULL! #NULL! 1 mellemrum i stedet for ; mellem to celler
#DIVISION/0! #DIV/0! 2 der divideres med 0 eller en tom celle
#VÆRDI! #VALUE! 3 der regnes med tekst
#REFERENCE! #REF! 4 formlen peger på en celle, der ikke findes (længere)
#NAVN? #NAME? 5 Excel kender ikke et funktionsnavn eller navn
#NUMMER! #NUM! 6 et tal eller en dato giver ikke mening for funktionen
#I/T #N/A 7 et opslag finder ikke værdien
#HENTER_DATA #GETTING_DATA 8 sjælden, ikke gennemgået her
#OVERLØB! #SPILL! 9 resultatet skal bruge flere celler, men der er ikke plads
#OPRETFORBINDELSE! #CONNECT! 10 en funktion kan ikke hente noget fra nettet
#BLOKERET! #BLOCKED! 11 adgangen er blokeret af indstillinger eller licens
#FELT! #FIELD! 13 feltet findes ikke i cellens datatype
#BEREGN! #CALC! 14 fx FILTRER uden resultater
#BUSY! #BUSY! – Excel venter stadig på et svar

Numrene i kolonnen FEJLTYPE er det, FEJLTYPE (engelsk: ERROR.TYPE) returnerede for fejlene i vores test. Bemærk navnet: funktionen hedder FEJLTYPE uden punktum. Tabellen er ikke udtømmende. Sjældnere fejlværdier, der hører til særlige funktioner, er ikke med.

D2 =FEJLTYPE(C2)
Giver et tal for fejlen i C2, fx 2 for #DIVISION/0! og 9 for #OVERLØB!.

Sådan finder du årsagen

  1. Find den celle, fejlen starter i. En fejl spreder sig til alle formler, der bruger cellen. I eksemplet længere nede giver =SUM(D2:D5) også #NAVN?, fordi én af cellerne har fejlen. Ret den første, ikke summen.
  2. Læs fejlnavnet og brug tabellen ovenfor til at gætte kategorien.
  3. Kig på formlen. =FORMELTEKST(C2) (engelsk: FORMULATEXT) viser formlen som tekst ved siden af resultatet, hvilket er praktisk, når du gennemgår mange celler.
  4. Evaluér en lang formel trin for trin. Ifølge Microsoft finder du funktionen under Formler › Formelrevision › Evaluer formel.

Excel kan også regne forkert uden at vise en fejl. En cirkulær reference gav bare 0 i vores test, og en formel, der vises som tekst, regner slet ikke.

Eksemplerne herunder bruger denne lille liste i K1:P4. N2 indeholder ét mellemrum, M4 indeholder teksten “4 stk”, og P2 indeholder varenummeret som tekst.

KLMNOP
1 Varenr Pris Antal Note Varenr som tekst
2 100149,95(ét mellemrum)1001
3 1002120,004
4 100315,504 stk
Eksempeldata i arket Fejl og årsager.

#DIVISION/0!

Du dividerer med 0 eller med en tom celle. Det sker typisk i “pris pr. stk.” eller procentandele, før alle tal er tastet ind.

C2 =L3/M2
M2 er tom. Resultat: #DIVISION/0!
G2 =HVIS(M2=0;"";L3/M2)
Viser en tom celle, indtil der står et tal i M2.

MIDDEL (engelsk: AVERAGE) giver også #DIVISION/0!, når området ikke indeholder nogen tal: =MIDDEL(N2:N4) gav fejlen, fordi N2:N4 kun rummer et mellemrum og tomme celler. =HVIS(TÆL(N2:N4)=0;"";MIDDEL(N2:N4)) viser i stedet en tom celle.

Excel kender ikke et ord i formlen. Vi har genskabt tre årsager:

Formel Problem Rettet
=LOPSLG(1001;K2:L4;2;FALSK) stavefejl i funktionsnavnet =LOPSLAG(1001;K2:L4;2;FALSK) → 49,95
=VLOOKUP(1001;K2:L4;2;FALSK) engelsk funktionsnavn i Excel på dansk =LOPSLAG(1001;K2:L4;2;FALSK) → 49,95
=HVIS(M3>2;mange;få) tekst uden anførselstegn =HVIS(M3>2;"mange";"få") → mange

Den midterste er den klassiske, når du kopierer fra en engelsk guide. Excel på dansk oversætter ikke VLOOKUP, når du skriver det selv. Se hvordan du oversætter formler fra engelske guides, også semikolon og decimalkomma. Samme guide forklarer, hvorfor #NAVN? også kan betyde, at modtagerens Excel-version ikke kender funktionen.

#VÆRDI!

Formlen regner med noget, der ikke er et tal.

C7 =L4*M4
M4 indeholder teksten "4 stk". Resultat: #VÆRDI!

Den lumske variant er en celle, der ser tom ud, men indeholder et mellemrum:

C8 =L2+N2
N2 indeholder ét mellemrum. Resultat: #VÆRDI!
G8 =SUM(L2;N2)
SUM springer tekst over. Resultat: 49,95

Den bedste rettelse er at rydde cellen eller skrive tallet uden tekst. Kan du ikke ændre data, kan du trække tallet ud: =L4*VÆRDI(TEKSTFØR(M4;" ")) gav 62. Tal fra andre systemer, der er gemt som tekst, har deres egen guide: tal gemt som tekst.

#REFERENCE!

Formlen peger på en celle, der ikke findes. Den hyppigste årsag er en slettet række eller kolonne. Vi skrev =A3*2 i C1 og slettede række 3. Bagefter stod formlen som =#REFERENCE!*2, og cellen viste #REFERENCE!. En =SUM(A2:A4) i samme ark overlevede, fordi Excel bare gjorde området mindre (=SUM(A2:A3)).

Referencen er væk fra formlen, så du skal skrive den rigtige celle ind igen.

To andre årsager, begge med et opslag uden for området:

Formel Problem Rettet
=LOPSLAG(1001;K2:L4;3;FALSK) kolonne 3, men området har kun 2 kolonner =LOPSLAG(1001;K2:L4;2;FALSK) → 49,95
=INDEKS(L2:L4;4) række 4, men området har kun 3 rækker =INDEKS(L2:L4;3) → 15,5

#I/T

#I/T betyder “ikke tilgængelig”: et opslag finder ikke det, du søger. Kan du se værdien i listen med dine egne øjne, er der en hel fejlsøgning at gå igennem, og den har sin egen guide: LOPSLAG virker ikke og giver #I/T.

C11 =LOPSLAG(1009;K2:L4;2;FALSK)
Varenummer 1009 findes ikke. Resultat: #I/T

Her er fejlen dog helt korrekt, og så handler det bare om at vise den pænt:

G11 =HVISIT(LOPSLAG(1009;K2:L4;2;FALSK);"Ukendt varenr")
Resultat: Ukendt varenr

#NUMMER!

Et tal passer ikke til funktionen.

Formel Problem Rettet
=DATO.FORSKEL(DATO(2026;9;30);DATO(2026;9;1);"d") startdatoen ligger efter slutdatoen =DATO.FORSKEL(DATO(2026;9;1);DATO(2026;9;30);"d") → 29
=KVROD(L3-200) kvadratroden af et negativt tal (-80) afhænger af, hvad du vil beregne

#NULL!

Et mellemrum mellem to referencer betyder i Excel “fællesmængden af de to områder”. Har de ingen celler til fælles, får du #NULL!. Typisk er det et glemt semikolon:

C15 =SUM(L2 L4)
Mellemrum i stedet for semikolon. Resultat: #NULL!
G15 =SUM(L2;L4)
Resultat: 65,45

#BEREGN!

Excel kan beregne formlen, men resultatet kan ikke vises. Det mest almindelige er FILTRER (engelsk: FILTER) uden rækker, der opfylder betingelsen:

C16 =FILTRER(K2:K4;L2:L4>500)
Ingen pris er over 500. Resultat: #BEREGN!
G16 =FILTRER(K2:K4;L2:L4>500;"Ingen")
Tredje argument bestemmer, hvad der vises, når intet findes. Resultat: Ingen

Du får også #BEREGN!, hvis du skriver en LAMBDA i en celle uden at kalde den: =LAMBDA(x;x*1,25) gav fejlen, mens =LAMBDA(x;x*1,25)(L3) gav 150.

#OVERLØB!

En formel returnerer flere værdier, men de celler, resultatet skal “løbe over” i, er ikke frie. I eksempelfilen står =K2:K4 i C18. Resultatet skal bruge C18:C20, men C19 er optaget, så C18 viser #OVERLØB!.

Der er flere andre årsager: flettede celler, formler i en Excel-tabel, og et opslag på en hel kolonne som =LOPSLAG(A:A;…). Vi har genskabt dem alle i #OVERLØB!: når en formel ikke kan løbe over.

#FELT!

#FELT! hører til datatyper, hvor en celle har felter, du kan hente med punktum eller FELTVÆRDI (engelsk: FIELDVALUE). Du får fejlen, når feltet ikke findes. Det gælder også, når cellen slet ikke er en datatype: både =FELTVÆRDI(K2;"Pris") og =K2.Pris gav #FELT!, fordi K2 bare er et tal.

Fejl fra funktioner, der henter data

Funktioner som BILLEDE (engelsk: IMAGE) og OVERSÆT (engelsk: TRANSLATE) henter noget over nettet. De gav tre fejl, du ikke møder i almindelige formler:

Formel Straks Efter 15 sekunder
=OVERSÆT("god morgen";"da";"en") #BUSY! Good morning
=BILLEDE("https://example.com/findes-ikke.png") #BUSY! #OPRETFORBINDELSE!
=BILLEDE("http://127.0.0.1/billede.png") #BLOKERET! #BLOKERET!

#BUSY! forsvinder af sig selv, når svaret kommer, og blev vist på engelsk i vores Excel på dansk. #OPRETFORBINDELSE! kom, fordi billedet ikke findes på adressen. Ifølge Microsoft betyder #BLOKERET! blandt andet, at BILLEDE har fået en adresse, der ikke er https, eller at sikkerhedsindstillinger forhindrer adgangen.

HVIS.FEJL eller HVISIT?

Begge funktioner erstatter en fejl med noget andet, men de fanger ikke det samme:

  • HVIS.FEJL (engelsk: IFERROR) fanger alle fejl.
  • HVISIT (engelsk: IFNA) fanger kun #I/T.

Det lyder som en detalje, men det afgør, om du opdager dine egne fejl. Her er en ordreliste, hvor beløbet slås op i en prisliste i H1:I4 (1001 = 49,95, 1002 = 120, 1003 = 15,50). I kolonne C og D er LOPSLAG stavet forkert:

C2 =HVIS.FEJL(B2*LOPSLG(A2;$H$2:$I$4;2;FALSK);0)
D2 =HVISIT(B2*LOPSLG(A2;$H$2:$I$4;2;FALSK);0)
E2 =HVISIT(B2*LOPSLAG(A2;$H$2:$I$4;2;FALSK);"Ukendt varenr")
ABCDEF
1 Varenr Antal HVIS.FEJL, tastefejl HVISIT, tastefejl HVISIT, korrekt HVISIT, uden $
2 100320,00#NAVN?31,0031,00
3 100140,00#NAVN?199,80Ukendt varenr
4 100210,00#NAVN?120,00Ukendt varenr
5 100930,00#NAVN?Ukendt varenrUkendt varenr
6 I alt0,00#NAVN?350,8031,00
Arket HVIS.FEJL skjuler. Kolonne C og D har tastefejlen LOPSLG. Kolonne F er den korrekte formel, men uden $ i prislisten.

Med HVIS.FEJL bliver tastefejlen til 0 i alle rækker, og totalen er 0,00 uden nogen advarsel. Med HVISIT står #NAVN? tydeligt, fordi det ikke er en #I/T-fejl. Kolonne E er den rigtige løsning: HVISIT håndterer kun det forventede tilfælde, at et varenummer ikke findes, og SUM springer teksten “Ukendt varenr” over.

Kolonne F viser grænsen. Uden $ flytter prislisten sig én række ned for hver række, formlen kopieres til (H3:I5, H4:I6 …). Så findes 1001 og 1002 ikke, og det giver #I/T, som HVISIT også skjuler. Fordi erstatningen er en synlig tekst og ikke 0, kan du dog se, at to kendte varenumre pludselig er “ukendte”. Totalen på 31,00 er forkert, men du har en chance for at opdage det. Mere om $ i absolutte og relative referencer.

Tommelfingerreglen:

  • Brug HVISIT til opslag, og kun hvor “ikke fundet” er et forventet resultat.
  • Erstat med en synlig tekst frem for 0, når tallet indgår i en sum.
  • Brug HVIS.FEJL på én bestemt fejl, du forventer, fx #DIVISION/0!. Brug den ikke til at pakke hele beregninger ind, “så det ser pænt ud”.